CaseData

7 files changed, 613 insertions, 29 deletions

diff --git a/build.zig b/build.zig
index 316292e..7272336 100644
--- a/build.zig
+++ b/build.zig
@@ -107,6 +107,46 @@ pub fn build(b: *std.Build) void {
     const run_num_gen_exe = b.addRunArtifact(num_gen_exe);
     const num_gen_out = run_num_gen_exe.addOutputFileArg("numeric.bin.z");
 
+    // Letter case properties
+    const case_prop_gen_exe = b.addExecutable(.{
+        .name = "case_prop",
+        .root_source_file = .{ .path = "codegen/case_prop.zig" },
+        .target = b.host,
+        .optimize = .Debug,
+    });
+    const run_case_prop_gen_exe = b.addRunArtifact(case_prop_gen_exe);
+    const case_prop_gen_out = run_case_prop_gen_exe.addOutputFileArg("case_prop.bin.z");
+
+    // Uppercase mappings
+    const upper_gen_exe = b.addExecutable(.{
+        .name = "upper",
+        .root_source_file = .{ .path = "codegen/upper.zig" },
+        .target = b.host,
+        .optimize = .Debug,
+    });
+    const run_upper_gen_exe = b.addRunArtifact(upper_gen_exe);
+    const upper_gen_out = run_upper_gen_exe.addOutputFileArg("upper.bin.z");
+
+    // Lowercase mappings
+    const lower_gen_exe = b.addExecutable(.{
+        .name = "lower",
+        .root_source_file = .{ .path = "codegen/lower.zig" },
+        .target = b.host,
+        .optimize = .Debug,
+    });
+    const run_lower_gen_exe = b.addRunArtifact(lower_gen_exe);
+    const lower_gen_out = run_lower_gen_exe.addOutputFileArg("lower.bin.z");
+
+    // Titlecase mappings
+    const title_gen_exe = b.addExecutable(.{
+        .name = "title",
+        .root_source_file = .{ .path = "codegen/title.zig" },
+        .target = b.host,
+        .optimize = .Debug,
+    });
+    const run_title_gen_exe = b.addRunArtifact(title_gen_exe);
+    const title_gen_out = run_title_gen_exe.addOutputFileArg("title.bin.z");
+
     // Modules we provide
     // Code points
     const code_point = b.addModule("code_point", .{
@@ -221,7 +261,7 @@ pub fn build(b: *std.Build) void {
     });
     gencat_data.addAnonymousImport("gencat", .{ .root_source_file = gencat_gen_out });
 
-    // Case
+    // Case folding
     const fold_data = b.createModule(.{
         .root_source_file = .{ .path = "src/FoldData.zig" },
         .target = target,
@@ -246,6 +286,18 @@ pub fn build(b: *std.Build) void {
     });
     num_data.addAnonymousImport("numeric", .{ .root_source_file = num_gen_out });
 
+    // Letter case
+    const case_data = b.createModule(.{
+        .root_source_file = .{ .path = "src/CaseData.zig" },
+        .target = target,
+        .optimize = optimize,
+    });
+    case_data.addImport("code_point", code_point);
+    case_data.addAnonymousImport("case_prop", .{ .root_source_file = case_prop_gen_out });
+    case_data.addAnonymousImport("upper", .{ .root_source_file = upper_gen_out });
+    case_data.addAnonymousImport("lower", .{ .root_source_file = lower_gen_out });
+    case_data.addAnonymousImport("title", .{ .root_source_file = title_gen_out });
+
     // Benchmark rig
     const exe = b.addExecutable(.{
         .name = "zg",
@@ -274,12 +326,12 @@ pub fn build(b: *std.Build) void {
 
     // Tests
     const exe_unit_tests = b.addTest(.{
-        .root_source_file = .{ .path = "src/NumericData.zig" },
+        .root_source_file = .{ .path = "src/CaseData.zig" },
         .target = target,
         .optimize = optimize,
     });
     // exe_unit_tests.root_module.addImport("ascii", ascii);
-    // exe_unit_tests.root_module.addImport("code_point", code_point);
+    exe_unit_tests.root_module.addImport("code_point", code_point);
     // exe_unit_tests.root_module.addImport("GraphemeData", grapheme_data);
     // exe_unit_tests.root_module.addImport("grapheme", grapheme);
     // exe_unit_tests.root_module.addImport("ziglyph", ziglyph.module("ziglyph"));
@@ -288,7 +340,11 @@ pub fn build(b: *std.Build) void {
     // exe_unit_tests.root_module.addImport("NormData", norm_data);
     // exe_unit_tests.root_module.addImport("Normalize", norm);
     // exe_unit_tests.root_module.addImport("FoldData", fold_data);
-    exe_unit_tests.root_module.addAnonymousImport("numeric", .{ .root_source_file = num_gen_out });
+    // exe_unit_tests.root_module.addAnonymousImport("numeric", .{ .root_source_file = num_gen_out });
+    exe_unit_tests.root_module.addAnonymousImport("case_prop", .{ .root_source_file = case_prop_gen_out });
+    exe_unit_tests.root_module.addAnonymousImport("upper", .{ .root_source_file = upper_gen_out });
+    exe_unit_tests.root_module.addAnonymousImport("lower", .{ .root_source_file = lower_gen_out });
+    exe_unit_tests.root_module.addAnonymousImport("title", .{ .root_source_file = title_gen_out });
     // exe_unit_tests.filter = "nfd !ASCII";
 
     const run_exe_unit_tests = b.addRunArtifact(exe_unit_tests);
diff --git a/codegen/case_prop.zig b/codegen/case_prop.zig
new file mode 100644
index 0000000..ce7ee0d
--- /dev/null
+++ b/codegen/case_prop.zig
@@ -0,0 +1,136 @@
+const std = @import("std");
+const builtin = @import("builtin");
+const mem = std.mem;
+
+const block_size = 256;
+const Block = [block_size]u8;
+
+const BlockMap = std.HashMap(
+    Block,
+    u16,
+    struct {
+        pub fn hash(_: @This(), k: Block) u64 {
+            var hasher = std.hash.Wyhash.init(0);
+            std.hash.autoHashStrat(&hasher, k, .DeepRecursive);
+            return hasher.final();
+        }
+
+        pub fn eql(_: @This(), a: Block, b: Block) bool {
+            return mem.eql(u8, &a, &b);
+        }
+    },
+    std.hash_map.default_max_load_percentage,
+);
+
+pub fn main() !void {
+    var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
+    defer arena.deinit();
+    const allocator = arena.allocator();
+
+    var flat_map = std.AutoHashMap(u21, u8).init(allocator);
+    defer flat_map.deinit();
+
+    var line_buf: [4096]u8 = undefined;
+
+    // Process DerivedCoreProperties.txt
+    var in_file = try std.fs.cwd().openFile("data/unicode/DerivedCoreProperties.txt", .{});
+    defer in_file.close();
+    var in_buf = std.io.bufferedReader(in_file.reader());
+    const in_reader = in_buf.reader();
+
+    while (try in_reader.readUntilDelimiterOrEof(&line_buf, '\n')) |line| {
+        if (line.len == 0 or line[0] == '#') continue;
+        const no_comment = if (mem.indexOfScalar(u8, line, '#')) |octo| line[0..octo] else line;
+
+        var field_iter = mem.tokenizeAny(u8, no_comment, "; ");
+        var current_code: [2]u21 = undefined;
+
+        var i: usize = 0;
+        while (field_iter.next()) |field| : (i += 1) {
+            switch (i) {
+                0 => {
+                    // Code point(s)
+                    if (mem.indexOf(u8, field, "..")) |dots| {
+                        current_code = .{
+                            try std.fmt.parseInt(u21, field[0..dots], 16),
+                            try std.fmt.parseInt(u21, field[dots + 2 ..], 16),
+                        };
+                    } else {
+                        const code = try std.fmt.parseInt(u21, field, 16);
+                        current_code = .{ code, code };
+                    }
+                },
+                1 => {
+                    // Props
+                    var bit: u8 = 0;
+
+                    if (mem.eql(u8, field, "Lowercase")) bit = 1;
+                    if (mem.eql(u8, field, "Uppercase")) bit = 2;
+                    if (mem.eql(u8, field, "Cased")) bit = 4;
+
+                    if (bit != 0) {
+                        for (current_code[0]..current_code[1] + 1) |cp| {
+                            const gop = try flat_map.getOrPut(@intCast(cp));
+                            if (!gop.found_existing) gop.value_ptr.* = 0;
+                            gop.value_ptr.* |= bit;
+                        }
+                    }
+                },
+                else => {},
+            }
+        }
+    }
+
+    var blocks_map = BlockMap.init(allocator);
+    defer blocks_map.deinit();
+
+    var stage1 = std.ArrayList(u16).init(allocator);
+    defer stage1.deinit();
+
+    var stage2 = std.ArrayList(u8).init(allocator);
+    defer stage2.deinit();
+
+    var block: Block = [_]u8{0} ** block_size;
+    var block_len: u16 = 0;
+
+    for (0..0x110000) |i| {
+        const cp: u21 = @intCast(i);
+        const prop = flat_map.get(cp) orelse 0;
+
+        // Process block
+        block[block_len] = prop;
+        block_len += 1;
+
+        if (block_len < block_size and cp != 0x10ffff) continue;
+
+        const gop = try blocks_map.getOrPut(block);
+        if (!gop.found_existing) {
+            gop.value_ptr.* = @intCast(stage2.items.len);
+            try stage2.appendSlice(&block);
+        }
+
+        try stage1.append(gop.value_ptr.*);
+        block_len = 0;
+    }
+
+    var args_iter = try std.process.argsWithAllocator(allocator);
+    defer args_iter.deinit();
+    _ = args_iter.skip();
+    const output_path = args_iter.next() orelse @panic("No output file arg!");
+
+    const compressor = std.compress.deflate.compressor;
+    var out_file = try std.fs.cwd().createFile(output_path, .{});
+    defer out_file.close();
+    var out_comp = try compressor(allocator, out_file.writer(), .{ .level = .best_compression });
+    defer out_comp.deinit();
+    const writer = out_comp.writer();
+
+    const endian = builtin.cpu.arch.endian();
+    try writer.writeInt(u16, @intCast(stage1.items.len), endian);
+    for (stage1.items) |i| try writer.writeInt(u16, i, endian);
+
+    try writer.writeInt(u16, @intCast(stage2.items.len), endian);
+    try writer.writeAll(stage2.items);
+
+    try out_comp.flush();
+}
diff --git a/codegen/lower.zig b/codegen/lower.zig
new file mode 100644
index 0000000..5a1f1b3
--- /dev/null
+++ b/codegen/lower.zig
@@ -0,0 +1,58 @@
+const std = @import("std");
+const builtin = @import("builtin");
+
+pub fn main() !void {
+    var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
+    defer arena.deinit();
+    const allocator = arena.allocator();
+
+    // Process UnicodeData.txt
+    var in_file = try std.fs.cwd().openFile("data/unicode/UnicodeData.txt", .{});
+    defer in_file.close();
+    var in_buf = std.io.bufferedReader(in_file.reader());
+    const in_reader = in_buf.reader();
+
+    var args_iter = try std.process.argsWithAllocator(allocator);
+    defer args_iter.deinit();
+    _ = args_iter.skip();
+    const output_path = args_iter.next() orelse @panic("No output file arg!");
+
+    const compressor = std.compress.deflate.compressor;
+    var out_file = try std.fs.cwd().createFile(output_path, .{});
+    defer out_file.close();
+    var out_comp = try compressor(allocator, out_file.writer(), .{ .level = .best_compression });
+    defer out_comp.deinit();
+    const writer = out_comp.writer();
+
+    const endian = builtin.cpu.arch.endian();
+    var line_buf: [4096]u8 = undefined;
+
+    lines: while (try in_reader.readUntilDelimiterOrEof(&line_buf, '\n')) |line| {
+        if (line.len == 0) continue;
+
+        var field_iter = std.mem.splitScalar(u8, line, ';');
+        var cps: [2]u24 = undefined;
+
+        var i: usize = 0;
+        while (field_iter.next()) |field| : (i += 1) {
+            switch (i) {
+                0 => cps[0] = try std.fmt.parseInt(u24, field, 16),
+
+                13 => {
+                    // Simple lowercase mapping
+                    if (field.len == 0) continue :lines;
+                    cps[1] = try std.fmt.parseInt(u24, field, 16);
+                },
+
+                2 => if (line[0] == '<') continue :lines,
+
+                else => {},
+            }
+        }
+
+        for (&cps) |cp| try writer.writeInt(u24, cp, endian);
+    }
+
+    try writer.writeInt(u24, 0, endian);
+    try out_comp.flush();
+}
diff --git a/codegen/numeric.zig b/codegen/numeric.zig
index 80fc7c2..ad8490c 100644
--- a/codegen/numeric.zig
+++ b/codegen/numeric.zig
@@ -1,5 +1,6 @@
 const std = @import("std");
 const builtin = @import("builtin");
+const mem = std.mem;
 
 const block_size = 256;
 const Block = [block_size]u8;
@@ -15,7 +16,7 @@ const BlockMap = std.HashMap(
         }
 
         pub fn eql(_: @This(), a: Block, b: Block) bool {
-            return std.mem.eql(u8, &a, &b);
+            return mem.eql(u8, &a, &b);
         }
     },
     std.hash_map.default_max_load_percentage,
@@ -31,17 +32,17 @@ pub fn main() !void {
 
     var line_buf: [4096]u8 = undefined;
 
-    // Process DerivedCombiningClass.txt
-    var num_file = try std.fs.cwd().openFile("data/unicode/extracted/DerivedNumericType.txt", .{});
-    defer num_file.close();
-    var num_buf = std.io.bufferedReader(num_file.reader());
-    const num_reader = num_buf.reader();
+    // Process DerivedNumericType.txt
+    var in_file = try std.fs.cwd().openFile("data/unicode/extracted/DerivedNumericType.txt", .{});
+    defer in_file.close();
+    var in_buf = std.io.bufferedReader(in_file.reader());
+    const in_reader = in_buf.reader();
 
-    while (try num_reader.readUntilDelimiterOrEof(&line_buf, '\n')) |line| {
+    while (try in_reader.readUntilDelimiterOrEof(&line_buf, '\n')) |line| {
         if (line.len == 0 or line[0] == '#') continue;
-        const no_comment = if (std.mem.indexOfScalar(u8, line, '#')) |octo| line[0..octo] else line;
+        const no_comment = if (mem.indexOfScalar(u8, line, '#')) |octo| line[0..octo] else line;
 
-        var field_iter = std.mem.tokenizeAny(u8, no_comment, "; ");
+        var field_iter = mem.tokenizeAny(u8, no_comment, "; ");
         var current_code: [2]u21 = undefined;
 
         var i: usize = 0;
@@ -49,7 +50,7 @@ pub fn main() !void {
             switch (i) {
                 0 => {
                     // Code point(s)
-                    if (std.mem.indexOf(u8, field, "..")) |dots| {
+                    if (mem.indexOf(u8, field, "..")) |dots| {
                         current_code = .{
                             try std.fmt.parseInt(u21, field[0..dots], 16),
                             try std.fmt.parseInt(u21, field[dots + 2 ..], 16),
@@ -61,25 +62,19 @@ pub fn main() !void {
                 },
                 1 => {
                     // Numeric type
-                    if (std.mem.eql(u8, field, "Numeric")) {
-                        for (current_code[0]..current_code[1] + 1) |cp| {
-                            const gop = try flat_map.getOrPut(@intCast(cp));
-                            if (!gop.found_existing) gop.value_ptr.* = 0;
-                            gop.value_ptr.* |= 1;
-                        }
-                    } else if (std.mem.eql(u8, field, "Digit")) {
-                        for (current_code[0]..current_code[1] + 1) |cp| {
-                            const gop = try flat_map.getOrPut(@intCast(cp));
-                            if (!gop.found_existing) gop.value_ptr.* = 0;
-                            gop.value_ptr.* |= 2;
-                        }
-                    } else if (std.mem.eql(u8, field, "Decimal")) {
+                    var bit: u8 = 0;
+
+                    if (mem.eql(u8, field, "Numeric")) bit = 1;
+                    if (mem.eql(u8, field, "Digit")) bit = 2;
+                    if (mem.eql(u8, field, "Decimal")) bit = 4;
+
+                    if (bit != 0) {
                         for (current_code[0]..current_code[1] + 1) |cp| {
                             const gop = try flat_map.getOrPut(@intCast(cp));
                             if (!gop.found_existing) gop.value_ptr.* = 0;
-                            gop.value_ptr.* |= 4;
+                            gop.value_ptr.* |= bit;
                         }
-                    } else continue;
+                    }
                 },
                 else => {},
             }
diff --git a/codegen/title.zig b/codegen/title.zig
new file mode 100644
index 0000000..653b812
--- /dev/null
+++ b/codegen/title.zig
@@ -0,0 +1,58 @@
+const std = @import("std");
+const builtin = @import("builtin");
+
+pub fn main() !void {
+    var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
+    defer arena.deinit();
+    const allocator = arena.allocator();
+
+    // Process UnicodeData.txt
+    var in_file = try std.fs.cwd().openFile("data/unicode/UnicodeData.txt", .{});
+    defer in_file.close();
+    var in_buf = std.io.bufferedReader(in_file.reader());
+    const in_reader = in_buf.reader();
+
+    var args_iter = try std.process.argsWithAllocator(allocator);
+    defer args_iter.deinit();
+    _ = args_iter.skip();
+    const output_path = args_iter.next() orelse @panic("No output file arg!");
+
+    const compressor = std.compress.deflate.compressor;
+    var out_file = try std.fs.cwd().createFile(output_path, .{});
+    defer out_file.close();
+    var out_comp = try compressor(allocator, out_file.writer(), .{ .level = .best_compression });
+    defer out_comp.deinit();
+    const writer = out_comp.writer();
+
+    const endian = builtin.cpu.arch.endian();
+    var line_buf: [4096]u8 = undefined;
+
+    lines: while (try in_reader.readUntilDelimiterOrEof(&line_buf, '\n')) |line| {
+        if (line.len == 0) continue;
+
+        var field_iter = std.mem.splitScalar(u8, line, ';');
+        var cps: [2]u24 = undefined;
+
+        var i: usize = 0;
+        while (field_iter.next()) |field| : (i += 1) {
+            switch (i) {
+                0 => cps[0] = try std.fmt.parseInt(u24, field, 16),
+
+                14 => {
+                    // Simple titlecase mapping
+                    if (field.len == 0) continue :lines;
+                    cps[1] = try std.fmt.parseInt(u24, field, 16);
+                },
+
+                2 => if (line[0] == '<') continue :lines,
+
+                else => {},
+            }
+        }
+
+        for (&cps) |cp| try writer.writeInt(u24, cp, endian);
+    }
+
+    try writer.writeInt(u24, 0, endian);
+    try out_comp.flush();
+}
diff --git a/codegen/upper.zig b/codegen/upper.zig
new file mode 100644
index 0000000..6fea608
--- /dev/null
+++ b/codegen/upper.zig
@@ -0,0 +1,58 @@
+const std = @import("std");
+const builtin = @import("builtin");
+
+pub fn main() !void {
+    var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
+    defer arena.deinit();
+    const allocator = arena.allocator();
+
+    // Process UnicodeData.txt
+    var in_file = try std.fs.cwd().openFile("data/unicode/UnicodeData.txt", .{});
+    defer in_file.close();
+    var in_buf = std.io.bufferedReader(in_file.reader());
+    const in_reader = in_buf.reader();
+
+    var args_iter = try std.process.argsWithAllocator(allocator);
+    defer args_iter.deinit();
+    _ = args_iter.skip();
+    const output_path = args_iter.next() orelse @panic("No output file arg!");
+
+    const compressor = std.compress.deflate.compressor;
+    var out_file = try std.fs.cwd().createFile(output_path, .{});
+    defer out_file.close();
+    var out_comp = try compressor(allocator, out_file.writer(), .{ .level = .best_compression });
+    defer out_comp.deinit();
+    const writer = out_comp.writer();
+
+    const endian = builtin.cpu.arch.endian();
+    var line_buf: [4096]u8 = undefined;
+
+    lines: while (try in_reader.readUntilDelimiterOrEof(&line_buf, '\n')) |line| {
+        if (line.len == 0) continue;
+
+        var field_iter = std.mem.splitScalar(u8, line, ';');
+        var cps: [2]u24 = undefined;
+
+        var i: usize = 0;
+        while (field_iter.next()) |field| : (i += 1) {
+            switch (i) {
+                0 => cps[0] = try std.fmt.parseInt(u24, field, 16),
+
+                12 => {
+                    // Simple uppercase mapping
+                    if (field.len == 0) continue :lines;
+                    cps[1] = try std.fmt.parseInt(u24, field, 16);
+                },
+
+                2 => if (line[0] == '<') continue :lines,
+
+                else => {},
+            }
+        }
+
+        for (&cps) |cp| try writer.writeInt(u24, cp, endian);
+    }
+
+    try writer.writeInt(u24, 0, endian);
+    try out_comp.flush();
+}
diff --git a/src/CaseData.zig b/src/CaseData.zig
new file mode 100644
index 0000000..38830e3
--- /dev/null
+++ b/src/CaseData.zig
@@ -0,0 +1,223 @@
+const std = @import("std");
+const builtin = @import("builtin");
+const compress = std.compress;
+const mem = std.mem;
+const testing = std.testing;
+const unicode = std.unicode;
+
+const CodePointIterator = @import("code_point").Iterator;
+
+allocator: mem.Allocator,
+case_map: [][3]u21,
+prop_s1: []u16 = undefined,
+prop_s2: []u8 = undefined,
+
+const Self = @This();
+
+pub fn init(allocator: mem.Allocator) !Self {
+    const decompressor = compress.deflate.decompressor;
+    const endian = builtin.cpu.arch.endian();
+
+    var self = Self{
+        .allocator = allocator,
+        .case_map = try allocator.alloc([3]u21, 0x110000),
+    };
+    errdefer allocator.free(self.case_map);
+
+    for (0..0x110000) |i| {
+        const cp: u21 = @intCast(i);
+        self.case_map[cp] = .{ cp, cp, cp };
+    }
+
+    // Uppercase
+    const upper_bytes = @embedFile("upper");
+    var upper_fbs = std.io.fixedBufferStream(upper_bytes);
+    var upper_decomp = try decompressor(allocator, upper_fbs.reader(), null);
+    defer upper_decomp.deinit();
+    var upper_reader = upper_decomp.reader();
+
+    while (true) {
+        const cp = try upper_reader.readInt(u24, endian);
+        if (cp == 0) break;
+        self.case_map[cp][0] = @intCast(try upper_reader.readInt(u24, endian));
+    }
+
+    // Lowercase
+    const lower_bytes = @embedFile("lower");
+    var lower_fbs = std.io.fixedBufferStream(lower_bytes);
+    var lower_decomp = try decompressor(allocator, lower_fbs.reader(), null);
+    defer lower_decomp.deinit();
+    var lower_reader = lower_decomp.reader();
+
+    while (true) {
+        const cp = try lower_reader.readInt(u24, endian);
+        if (cp == 0) break;
+        self.case_map[cp][1] = @intCast(try lower_reader.readInt(u24, endian));
+    }
+
+    // Titlercase
+    const title_bytes = @embedFile("title");
+    var title_fbs = std.io.fixedBufferStream(title_bytes);
+    var title_decomp = try decompressor(allocator, title_fbs.reader(), null);
+    defer title_decomp.deinit();
+    var title_reader = title_decomp.reader();
+
+    while (true) {
+        const cp = try title_reader.readInt(u24, endian);
+        if (cp == 0) break;
+        self.case_map[cp][2] = @intCast(try title_reader.readInt(u24, endian));
+    }
+
+    // Case properties
+    const cp_bytes = @embedFile("case_prop");
+    var cp_fbs = std.io.fixedBufferStream(cp_bytes);
+    var cp_decomp = try decompressor(allocator, cp_fbs.reader(), null);
+    defer cp_decomp.deinit();
+    var cp_reader = cp_decomp.reader();
+
+    const stage_1_len: u16 = try cp_reader.readInt(u16, endian);
+    self.prop_s1 = try allocator.alloc(u16, stage_1_len);
+    errdefer allocator.free(self.prop_s1);
+    for (0..stage_1_len) |i| self.prop_s1[i] = try cp_reader.readInt(u16, endian);
+
+    const stage_2_len: u16 = try cp_reader.readInt(u16, endian);
+    self.prop_s2 = try allocator.alloc(u8, stage_2_len);
+    errdefer allocator.free(self.prop_s2);
+    _ = try cp_reader.readAll(self.prop_s2);
+
+    return self;
+}
+
+pub fn deinit(self: *Self) void {
+    self.allocator.free(self.case_map);
+    self.allocator.free(self.prop_s1);
+    self.allocator.free(self.prop_s2);
+}
+
+// Returns true if `cp` is either upper, lower, or title case.
+pub inline fn isCased(self: Self, cp: u21) bool {
+    return self.prop_s2[self.prop_s1[cp >> 8] + (cp & 0xff)] & 4 == 4;
+}
+
+// Returns true if `cp` is uppercase.
+pub fn isUpper(self: Self, cp: u21) bool {
+    if (!self.isCased(cp)) return true;
+    return self.prop_s2[self.prop_s1[cp >> 8] + (cp & 0xff)] & 2 == 2;
+}
+
+/// Returns true if `str` is all uppercase.
+pub fn isUpperStr(self: Self, str: []const u8) bool {
+    var iter = CodePointIterator{ .bytes = str };
+
+    return while (iter.next()) |cp| {
+        if (!self.isUpper(cp.code)) break false;
+    } else true;
+}
+
+test "isUpperStr" {
+    var cd = try init(testing.allocator);
+    defer cd.deinit();
+
+    try testing.expect(cd.isUpperStr("HELLO, WORLD 2112!"));
+    try testing.expect(!cd.isUpperStr("hello, world 2112!"));
+    try testing.expect(!cd.isUpperStr("Hello, World 2112!"));
+}
+
+/// Returns a new string with all letters in uppercase.
+/// Caller must free returned bytes with `allocator`.
+pub fn toUpperStr(
+    self: Self,
+    allocator: mem.Allocator,
+    str: []const u8,
+) ![]u8 {
+    var bytes = std.ArrayList(u8).init(allocator);
+    defer bytes.deinit();
+
+    var iter = CodePointIterator{ .bytes = str };
+    var buf: [4]u8 = undefined;
+
+    while (iter.next()) |cp| {
+        const len = try unicode.utf8Encode(self.toUpper(cp.code), &buf);
+        try bytes.appendSlice(buf[0..len]);
+    }
+
+    return try bytes.toOwnedSlice();
+}
+
+test "toUpperStr" {
+    var cd = try init(testing.allocator);
+    defer cd.deinit();
+
+    const uppered = try cd.toUpperStr(testing.allocator, "Hello, World 2112!");
+    defer testing.allocator.free(uppered);
+    try testing.expectEqualStrings("HELLO, WORLD 2112!", uppered);
+}
+
+/// Returns uppercase mapping for `cp`.
+pub inline fn toUpper(self: Self, cp: u21) u21 {
+    return self.case_map[cp][0];
+}
+
+// Returns true if `cp` is lowercase.
+pub fn isLower(self: Self, cp: u21) bool {
+    if (!self.isCased(cp)) return true;
+    return self.prop_s2[self.prop_s1[cp >> 8] + (cp & 0xff)] & 1 == 1;
+}
+
+/// Returns lowercase mapping for `cp`.
+pub inline fn toLower(self: Self, cp: u21) u21 {
+    return self.case_map[cp][1];
+}
+
+/// Returns true if `str` is all lowercase.
+pub fn isLowerStr(self: Self, str: []const u8) bool {
+    var iter = CodePointIterator{ .bytes = str };
+
+    return while (iter.next()) |cp| {
+        if (!self.isLower(cp.code)) break false;
+    } else true;
+}
+
+test "isLowerStr" {
+    var cd = try init(testing.allocator);
+    defer cd.deinit();
+
+    try testing.expect(cd.isLowerStr("hello, world 2112!"));
+    try testing.expect(!cd.isLowerStr("HELLO, WORLD 2112!"));
+    try testing.expect(!cd.isLowerStr("Hello, World 2112!"));
+}
+
+/// Returns a new string with all letters in lowercase.
+/// Caller must free returned bytes with `allocator`.
+pub fn toLowerStr(
+    self: Self,
+    allocator: mem.Allocator,
+    str: []const u8,
+) ![]u8 {
+    var bytes = std.ArrayList(u8).init(allocator);
+    defer bytes.deinit();
+
+    var iter = CodePointIterator{ .bytes = str };
+    var buf: [4]u8 = undefined;
+
+    while (iter.next()) |cp| {
+        const len = try unicode.utf8Encode(self.toLower(cp.code), &buf);
+        try bytes.appendSlice(buf[0..len]);
+    }
+
+    return try bytes.toOwnedSlice();
+}
+
+test "toLowerStr" {
+    var cd = try init(testing.allocator);
+    defer cd.deinit();
+
+    const lowered = try cd.toLowerStr(testing.allocator, "Hello, World 2112!");
+    defer testing.allocator.free(lowered);
+    try testing.expectEqualStrings("hello, world 2112!", lowered);
+}
+
+/// Returns titlecase mapping for `cp`.
+pub inline fn toTitle(self: Self, cp: u21) u21 {
+    return self.case_map[cp][2];
+}