blob: 25933b5366e931bda81d2c510e8dbb86d40cbbda (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
|
plugins {
`maven-publish`
id("io.freefair.lombok")
id("org.quiltmc.loom")
}
val chippedVersion: String by project
val groupid: String by project
val jakartaAnnotationVersion: String by project
val loaderVersion: String by project
val modid: String by project
val modVersion: String by project
val minecraftVersion: String by project
val patchouliVersion: String by project
val quiltMappings: String by project
val quiltedFabricApiVersion: String by project
val wthitVersion: String by project
group = groupid
version = modVersion
repositories {
maven {
// For Patchouli
url = uri("https://maven.blamejared.com")
content {
includeGroup("vazkii.patchouli")
}
}
maven {
// For Chipped
url = uri("https://maven.resourcefulbees.com/repository/maven-public/")
content {
includeGroup("com.teamresourceful")
includeGroup("com.teamresourceful.resourcefullib")
includeGroup("com.terraformersmc")
includeGroup("earth.terrarium.athena")
includeGroup("earth.terrarium.chipped")
}
}
maven {
// For WTHIT
url = uri("https://maven2.bai.lol")
content {
includeGroup("lol.bai")
includeGroup("mcp.mobius.waila")
}
}
}
loom {
mods {
register(modid) {
sourceSet("main")
}
}
}
dependencies {
minecraft("com.mojang:minecraft:${minecraftVersion}")
mappings(loom.layered {
mappings("org.quiltmc:quilt-mappings:${minecraftVersion}+build.${quiltMappings}:intermediary-v2")
officialMojangMappings()
})
modImplementation("org.quiltmc:quilt-loader:${loaderVersion}")
modImplementation("org.quiltmc.quilted-fabric-api:quilted-fabric-api:${quiltedFabricApiVersion}-${minecraftVersion}")
modImplementation("vazkii.patchouli:Patchouli:${patchouliVersion}") {
exclude(group = "net.fabricmc")
exclude(group = "net.fabricmc.fabric-api")
}
modCompileOnly("mcp.mobius.waila:wthit-api:quilt-${wthitVersion}")
modCompileOnly("earth.terrarium.chipped:chipped-fabric-${minecraftVersion}:${chippedVersion}")
compileOnly("jakarta.annotation:jakarta.annotation-api:${jakartaAnnotationVersion}")
}
java {
toolchain {
languageVersion.set(JavaLanguageVersion.of(17))
}
withJavadocJar()
withSourcesJar()
}
publishing {
publications {
create<MavenPublication>("maven") {
from(components["java"])
}
}
repositories {
maven {
url = uri("https://mvn.enes.lv/")
credentials {
username = (findProperty("mvnUsername") ?: System.getenv("MVN_USERNAME") ?: "").toString()
password = (findProperty("mvnPassword") ?: System.getenv("MVN_PASSWORD") ?: "").toString()
}
}
}
}
tasks.processResources {
inputs.property("loader_version", loaderVersion)
inputs.property("minecraft_version", minecraftVersion)
inputs.property("patchouli_version", patchouliVersion)
inputs.property("quilted_fabric_api_version", quiltedFabricApiVersion)
inputs.property("version", version)
filesMatching("quilt.mod.json") {
expand(
"loader_version" to loaderVersion,
"minecraft_version" to minecraftVersion,
"patchouli_version" to patchouliVersion,
"quilted_fabric_api_version" to quiltedFabricApiVersion,
"version" to version
)
}
}
tasks.withType<JavaCompile>().configureEach {
options.encoding = "UTF-8"
options.release = 17
}
tasks.javadoc {
(options as StandardJavadocDocletOptions).addBooleanOption("html5", true)
}
tasks.jar {
from("LICENSE") {
rename { "${it}_${name}" }
}
}
|
