From ad306724ae574b1a22abbcb6de37e65a69db82e4 Mon Sep 17 00:00:00 2001
From: Jose Colon Rodriguez
Date: Mon, 26 Feb 2024 20:22:41 -0400
Subject: Using NormData nfkd

---
 src/CanonData.zig | 56 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 src/CanonData.zig

(limited to 'src/CanonData.zig')

diff --git a/src/CanonData.zig b/src/CanonData.zig
new file mode 100644
index 0000000..81d3eec
--- /dev/null
+++ b/src/CanonData.zig
@@ -0,0 +1,56 @@
+const std = @import("std");
+const builtin = @import("builtin");
+const compress = std.compress;
+const mem = std.mem;
+
+allocator: mem.Allocator,
+nfc: std.AutoHashMap([2]u21, u21),
+nfd: [][2]u21 = undefined,
+
+const Self = @This();
+
+pub fn init(allocator: mem.Allocator) !Self {
+    const decompressor = compress.deflate.decompressor;
+    const in_bytes = @embedFile("canon");
+    var in_fbs = std.io.fixedBufferStream(in_bytes);
+    var in_decomp = try decompressor(allocator, in_fbs.reader(), null);
+    defer in_decomp.deinit();
+    var reader = in_decomp.reader();
+
+    const endian = builtin.cpu.arch.endian();
+    var self = Self{
+        .allocator = allocator,
+        .nfc = std.AutoHashMap([2]u21, u21).init(allocator),
+        .nfd = try allocator.alloc([2]u21, 0x110000),
+    };
+
+    for (0..0x110000) |i| self.nfd[i] = .{ @intCast(i), 0 };
+
+    while (true) {
+        const len: u8 = try reader.readInt(u8, endian);
+        if (len == 0) break;
+        const cp = try reader.readInt(u24, endian);
+        self.nfd[cp][0] = @intCast(try reader.readInt(u24, endian));
+        if (len == 3) {
+            self.nfd[cp][1] = @intCast(try reader.readInt(u24, endian));
+            try self.nfc.put(self.nfd[cp], @intCast(cp));
+        }
+    }
+
+    return self;
+}
+
+pub fn deinit(self: *Self) void {
+    self.nfc.deinit();
+    self.allocator.free(self.nfd);
+}
+
+/// Returns canonical decomposition for `cp`.
+pub inline fn toNfd(self: Self, cp: u21) [2]u21 {
+    return self.nfd[cp];
+}
+
+// Returns the primary composite for the codepoints in `cp`.
+pub inline fn toNfc(self: Self, cps: [2]u21) ?u21 {
+    return self.nfc.get(cps);
+}
-- 
cgit v1.2.3