From ad306724ae574b1a22abbcb6de37e65a69db82e4 Mon Sep 17 00:00:00 2001
From: Jose Colon Rodriguez
Date: Mon, 26 Feb 2024 20:22:41 -0400
Subject: Using NormData nfkd

---
 codegen/compat.zig | 65 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 codegen/compat.zig

(limited to 'codegen/compat.zig')

diff --git a/codegen/compat.zig b/codegen/compat.zig
new file mode 100644
index 0000000..916d4d0
--- /dev/null
+++ b/codegen/compat.zig
@@ -0,0 +1,65 @@
+const std = @import("std");
+const builtin = @import("builtin");
+
+pub fn main() !void {
+    var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
+    defer arena.deinit();
+    const allocator = arena.allocator();
+
+    // Process DerivedEastAsianWidth.txt
+    var in_file = try std.fs.cwd().openFile("data/unicode/UnicodeData.txt", .{});
+    defer in_file.close();
+    var in_buf = std.io.bufferedReader(in_file.reader());
+    const in_reader = in_buf.reader();
+
+    var args_iter = try std.process.argsWithAllocator(allocator);
+    defer args_iter.deinit();
+    _ = args_iter.skip();
+    const output_path = args_iter.next() orelse @panic("No output file arg!");
+
+    const compressor = std.compress.deflate.compressor;
+    var out_file = try std.fs.cwd().createFile(output_path, .{});
+    defer out_file.close();
+    var out_comp = try compressor(allocator, out_file.writer(), .{ .level = .best_compression });
+    defer out_comp.deinit();
+    const writer = out_comp.writer();
+
+    const endian = builtin.cpu.arch.endian();
+    var line_buf: [4096]u8 = undefined;
+
+    lines: while (try in_reader.readUntilDelimiterOrEof(&line_buf, '\n')) |line| {
+        if (line.len == 0) continue;
+
+        var field_iter = std.mem.splitScalar(u8, line, ';');
+        var cps: [19]u24 = undefined;
+        var len: u8 = 1;
+
+        var i: usize = 0;
+        while (field_iter.next()) |field| : (i += 1) {
+            switch (i) {
+                0 => cps[0] = try std.fmt.parseInt(u24, field, 16),
+
+                5 => {
+                    // Not compatibility.
+                    if (field.len == 0 or field[0] != '<') continue :lines;
+                    var cp_iter = std.mem.tokenizeScalar(u8, field, ' ');
+                    _ = cp_iter.next(); // <compat type>
+
+                    while (cp_iter.next()) |cp_str| : (len += 1) {
+                        cps[len] = try std.fmt.parseInt(u24, cp_str, 16);
+                    }
+                },
+
+                2 => if (line[0] == '<') continue :lines,
+
+                else => {},
+            }
+        }
+
+        try writer.writeInt(u8, @intCast(len), endian);
+        for (cps[0..len]) |cp| try writer.writeInt(u24, cp, endian);
+    }
+
+    try writer.writeInt(u16, 0, endian);
+    try out_comp.flush();
+}
-- 
cgit v1.2.3