Add Emoji module and codegen/emoji

4 files changed, 333 insertions, 0 deletions

diff --git a/README.md b/README.md
index bfa8d5e..5912ce4 100644
--- a/README.md
+++ b/README.md
@@ -520,6 +520,34 @@ test "Scripts" {
 }
 ```
 
+## Emoji
+
+To get information about emoji and emoji-like characters, use the `Emoji` module.
+
+In your `build.zig`:
+
+```zig
+exe.root_module.addImport("Emoji", zg.module("Emoji"));
+```
+
+In your code:
+
+```zig
+const Emoji = @import("Emoji");
+
+test "Emoji" {
+    const emoji = try Emoji.init(allocator);
+    defer emoji.deinit(allocator);
+
+    try expect(emoji.isEmoji(0x1F415)); // 🐕
+    try expect(emoji.isEmojiPresentation(0x1F408)); // 🐈
+    try expect(emoji.isEmojiModifier(0x1F3FF)); // 🏿
+    try expect(emoji.isEmojiModifierBase(0x1F977)); // 🥷
+    try expect(emoji.isEmojiComponent(0x1F9B0)); // 🦰
+    try expect(emoji.isExtendedPictographic(0x1F005)); // 🀅
+}
+```
+
 ## Relation to Ziglyph
 
 zg is a total re-write of some of the components of Ziglyph. The idea was to
diff --git a/build.zig b/build.zig
index 58fd3e7..839cf13 100644
--- a/build.zig
+++ b/build.zig
@@ -22,6 +22,16 @@ pub fn build(b: *std.Build) void {
     const run_gbp_gen_exe = b.addRunArtifact(gbp_gen_exe);
     const gbp_gen_out = run_gbp_gen_exe.addOutputFileArg("gbp.bin.z");
 
+    // Emoji
+    const emoji_gen_exe = b.addExecutable(.{
+        .name = "emoji",
+        .root_source_file = b.path("codegen/emoji.zig"),
+        .target = b.graph.host,
+        .optimize = .Debug,
+    });
+    const run_emoji_gen_exe = b.addRunArtifact(emoji_gen_exe);
+    const emoji_gen_out = run_emoji_gen_exe.addOutputFileArg("emoji.bin.z");
+
     // Display width
     const cjk = b.option(bool, "cjk", "Ambiguous code points are wide (display width: 2).") orelse false;
     const options = b.addOptions();
@@ -215,6 +225,22 @@ pub fn build(b: *std.Build) void {
     });
     const grapheme_tr = b.addRunArtifact(grapheme_t);
 
+    // Emoji module
+    const emoji = b.addModule("Emoji", .{
+        .root_source_file = b.path("src/Emoji.zig"),
+        .target = target,
+        .optimize = optimize,
+    });
+    emoji.addAnonymousImport("emoji", .{ .root_source_file = emoji_gen_out });
+
+    const emoji_t = b.addTest(.{
+        .name = "Emoji",
+        .root_module = emoji,
+        .target = target,
+        .optimize = optimize,
+    });
+    const emoji_tr = b.addRunArtifact(emoji_t);
+
     // ASCII utilities
     const ascii = b.addModule("ascii", .{
         .root_source_file = b.path("src/ascii.zig"),
@@ -452,6 +478,7 @@ pub fn build(b: *std.Build) void {
     test_step.dependOn(&code_point_tr.step);
     test_step.dependOn(&display_width_tr.step);
     test_step.dependOn(&grapheme_tr.step);
+    test_step.dependOn(&emoji_tr.step);
     test_step.dependOn(&ascii_tr.step);
     test_step.dependOn(&ccc_data_tr.step);
     test_step.dependOn(&canon_data_tr.step);
diff --git a/codegen/emoji.zig b/codegen/emoji.zig
new file mode 100644
index 0000000..0a4dbe6
--- /dev/null
+++ b/codegen/emoji.zig
@@ -0,0 +1,146 @@
+const std = @import("std");
+const builtin = @import("builtin");
+
+pub const Emoji = packed struct {
+    Emoji: bool = false,
+    Emoji_Presentation: bool = false,
+    Emoji_Modifier: bool = false,
+    Emoji_Modifier_Base: bool = false,
+    Emoji_Component: bool = false,
+    Extended_Pictographic: bool = false,
+};
+
+const block_size = 256;
+const Block = [block_size]u6;
+
+comptime {
+    if (@bitSizeOf(u6) != @bitSizeOf(Emoji)) {
+        @compileError("Emoji doesn't have expected bit size.");
+    }
+}
+
+const BlockMap = std.HashMap(
+    Block,
+    u16,
+    struct {
+        pub fn hash(_: @This(), k: Block) u64 {
+            var hasher = std.hash.Wyhash.init(0);
+            std.hash.autoHashStrat(&hasher, k, .DeepRecursive);
+            return hasher.final();
+        }
+
+        pub fn eql(_: @This(), a: Block, b: Block) bool {
+            return std.mem.eql(u6, &a, &b);
+        }
+    },
+    std.hash_map.default_max_load_percentage,
+);
+
+pub fn main() !void {
+    var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
+    defer arena.deinit();
+    const allocator = arena.allocator();
+
+    var emoji_map = std.AutoHashMap(u21, Emoji).init(allocator);
+    defer emoji_map.deinit();
+
+    var line_buf: [4096]u8 = undefined;
+
+    // Process Emoji
+    var in_file = try std.fs.cwd().openFile("data/unicode/emoji/emoji-data.txt", .{});
+    defer in_file.close();
+    var in_buf = std.io.bufferedReader(in_file.reader());
+    const in_reader = in_buf.reader();
+
+    while (try in_reader.readUntilDelimiterOrEof(&line_buf, '\n')) |line| {
+        if (line.len == 0 or line[0] == '#') continue;
+        const no_comment = if (std.mem.indexOfScalar(u8, line, '#')) |octo| line[0..octo] else line;
+
+        var field_iter = std.mem.tokenizeAny(u8, no_comment, "; ");
+        var current_code: [2]u21 = undefined;
+
+        var i: usize = 0;
+        while (field_iter.next()) |field| : (i += 1) {
+            switch (i) {
+                0 => {
+                    // Code point(s)
+                    if (std.mem.indexOf(u8, field, "..")) |dots| {
+                        current_code = .{
+                            try std.fmt.parseInt(u21, field[0..dots], 16),
+                            try std.fmt.parseInt(u21, field[dots + 2 ..], 16),
+                        };
+                    } else {
+                        const code = try std.fmt.parseInt(u21, field, 16);
+                        current_code = .{ code, code };
+                    }
+                },
+                1 => {
+                    // Prop
+                    const prop = std.meta.stringToEnum(std.meta.FieldEnum(Emoji), field) orelse return error.InvalidProp;
+                    for (current_code[0]..current_code[1] + 1) |code| {
+                        const cp: u21 = @intCast(code);
+                        const gop = try emoji_map.getOrPut(cp);
+                        if (!gop.found_existing) gop.value_ptr.* = .{};
+                        switch (prop) {
+                            inline else => |tag| {
+                                @field(gop.value_ptr.*, @tagName(tag)) = true;
+                            },
+                        }
+                    }
+                },
+                else => {},
+            }
+        }
+    }
+
+    var blocks_map = BlockMap.init(allocator);
+    defer blocks_map.deinit();
+
+    var stage1 = std.ArrayList(u16).init(allocator);
+    defer stage1.deinit();
+
+    var stage2 = std.ArrayList(u6).init(allocator);
+    defer stage2.deinit();
+
+    var block: Block = [_]u6{0} ** block_size;
+    var block_len: u16 = 0;
+
+    for (0..0x110000) |i| {
+        const cp: u21 = @intCast(i);
+        const emoji = emoji_map.get(cp) orelse Emoji{};
+
+        block[block_len] = @bitCast(emoji);
+        block_len += 1;
+
+        if (block_len < block_size and cp != 0x10ffff) continue;
+
+        const gop = try blocks_map.getOrPut(block);
+        if (!gop.found_existing) {
+            gop.value_ptr.* = @intCast(stage2.items.len);
+            try stage2.appendSlice(&block);
+        }
+
+        try stage1.append(gop.value_ptr.*);
+        block_len = 0;
+    }
+
+    var args_iter = try std.process.argsWithAllocator(allocator);
+    defer args_iter.deinit();
+    _ = args_iter.skip();
+    const output_path = args_iter.next() orelse @panic("No output file arg!");
+
+    const compressor = std.compress.flate.deflate.compressor;
+    var out_file = try std.fs.cwd().createFile(output_path, .{});
+    defer out_file.close();
+    var out_comp = try compressor(.raw, out_file.writer(), .{ .level = .best });
+    const writer = out_comp.writer();
+
+    const endian = builtin.cpu.arch.endian();
+    try writer.writeInt(u16, @intCast(stage1.items.len), endian);
+    for (stage1.items) |i| try writer.writeInt(u16, i, endian);
+
+    try writer.writeInt(u16, @intCast(stage2.items.len), endian);
+    for (stage2.items) |i| try writer.writeInt(u8, i, endian);
+
+    try out_comp.flush();
+}
diff --git a/src/Emoji.zig b/src/Emoji.zig
new file mode 100644
index 0000000..bf7014d
--- /dev/null
+++ b/src/Emoji.zig
@@ -0,0 +1,132 @@
+const std = @import("std");
+const builtin = @import("builtin");
+const mem = std.mem;
+const Allocator = mem.Allocator;
+const compress = std.compress;
+const unicode = std.unicode;
+
+const CodePoint = @import("code_point").CodePoint;
+const CodePointIterator = @import("code_point").Iterator;
+
+s1: []u16 = undefined,
+s2: []u6 = undefined,
+
+const Emoji = @This();
+
+// This must be an exact match of `Emoji` from `codegen/emoji.zig`.
+pub const Properties = packed struct {
+    Emoji: bool = false,
+    Emoji_Presentation: bool = false,
+    Emoji_Modifier: bool = false,
+    Emoji_Modifier_Base: bool = false,
+    Emoji_Component: bool = false,
+    Extended_Pictographic: bool = false,
+};
+
+pub fn init(allocator: Allocator) Allocator.Error!Emoji {
+    var emoji = Emoji{};
+    try emoji.setup(allocator);
+    return emoji;
+}
+
+pub fn setup(emoji: *Emoji, allocator: Allocator) Allocator.Error!void {
+    const decompressor = compress.flate.inflate.decompressor;
+    const in_bytes = @embedFile("emoji");
+    var in_fbs = std.io.fixedBufferStream(in_bytes);
+    var in_decomp = decompressor(.raw, in_fbs.reader());
+    var reader = in_decomp.reader();
+
+    const endian = builtin.cpu.arch.endian();
+
+    const s1_len: u16 = reader.readInt(u16, endian) catch unreachable;
+    emoji.s1 = try allocator.alloc(u16, s1_len);
+    errdefer allocator.free(emoji.s1);
+    for (0..s1_len) |i| emoji.s1[i] = reader.readInt(u16, endian) catch unreachable;
+
+    const s2_len: u16 = reader.readInt(u16, endian) catch unreachable;
+    emoji.s2 = try allocator.alloc(u6, s2_len);
+    errdefer allocator.free(emoji.s2);
+    for (0..s2_len) |i| emoji.s2[i] = @intCast(reader.readInt(u8, endian) catch unreachable);
+}
+
+pub fn deinit(emoji: *const Emoji, allocator: Allocator) void {
+    allocator.free(emoji.s1);
+    allocator.free(emoji.s2);
+}
+
+/// Lookup the emoji properties for a code point.
+fn properties(emoji: Emoji, cp: u21) Properties {
+    return @bitCast(emoji.s2[emoji.s1[cp >> 8] + (cp & 0xff)]);
+}
+
+pub fn isEmoji(emoji: Emoji, cp: u21) bool {
+    return properties(emoji, cp).Emoji;
+}
+
+pub fn isEmojiPresentation(emoji: Emoji, cp: u21) bool {
+    return properties(emoji, cp).Emoji_Presentation;
+}
+
+pub fn isEmojiModifier(emoji: Emoji, cp: u21) bool {
+    return properties(emoji, cp).Emoji_Modifier;
+}
+
+pub fn isEmojiModifierBase(emoji: Emoji, cp: u21) bool {
+    return properties(emoji, cp).Emoji_Modifier_Base;
+}
+
+pub fn isEmojiComponent(emoji: Emoji, cp: u21) bool {
+    return properties(emoji, cp).Emoji_Component;
+}
+
+pub fn isExtendedPictographic(emoji: Emoji, cp: u21) bool {
+    return properties(emoji, cp).Extended_Pictographic;
+}
+
+test "isEmoji" {
+    const emoji = try Emoji.init(std.testing.allocator);
+    defer emoji.deinit(std.testing.allocator);
+
+    try std.testing.expect(emoji.isEmoji(0x1F415)); // 🐕
+    try std.testing.expect(!emoji.isEmoji(0x3042)); // あ
+}
+
+test "isEmojiPresentation" {
+    const emoji = try Emoji.init(std.testing.allocator);
+    defer emoji.deinit(std.testing.allocator);
+
+    try std.testing.expect(emoji.isEmojiPresentation(0x1F408)); // 🐈
+    try std.testing.expect(!emoji.isEmojiPresentation(0x267E)); // ♾️
+}
+
+test "isEmojiModifier" {
+    const emoji = try Emoji.init(std.testing.allocator);
+    defer emoji.deinit(std.testing.allocator);
+
+    try std.testing.expect(emoji.isEmojiModifier(0x1F3FF)); // 🏿
+    try std.testing.expect(!emoji.isEmojiModifier(0x1F385)); // 🎅
+}
+
+test "isEmojiModifierBase" {
+    const emoji = try Emoji.init(std.testing.allocator);
+    defer emoji.deinit(std.testing.allocator);
+
+    try std.testing.expect(emoji.isEmojiModifierBase(0x1F977)); // 🥷
+    try std.testing.expect(!emoji.isEmojiModifierBase(0x1F4F8)); // 📸
+}
+
+test "isEmojiComponent" {
+    const emoji = try Emoji.init(std.testing.allocator);
+    defer emoji.deinit(std.testing.allocator);
+
+    try std.testing.expect(emoji.isEmojiComponent(0x1F9B0)); // 🦰
+    try std.testing.expect(!emoji.isEmojiComponent(0x1F9B5)); // 🦵
+}
+
+test "isExtendedPictographic" {
+    const emoji = try Emoji.init(std.testing.allocator);
+    defer emoji.deinit(std.testing.allocator);
+
+    try std.testing.expect(emoji.isExtendedPictographic(0x1F005)); // 🀅
+    try std.testing.expect(!emoji.isExtendedPictographic(0x2A)); // *
+}