added scm rev generation on Linux/cmake

10 files changed, 211 insertions, 53 deletions

diff --git a/.gitignore b/.gitignore
index 8a794aa0a..1b124ad3e 100644
--- a/.gitignore
+++ b/.gitignore
@@ -23,5 +23,3 @@ ipch/
 build/
 bin/
 
-# GIT revision number
-src/common/scm_rev.h
diff --git a/CMakeLists.txt b/CMakeLists.txt
index ed678d619..83a819a7f 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -29,6 +29,12 @@ if(NOT DISABLE_QT4)
     endif()
 endif()
 
+# generate git revision information
+list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/externals/cmake-modules/")
+include(GetGitRevisionDescription)
+get_git_head_revision(GIT_REF_SPEC GIT_REV)
+git_describe(GIT_DESC --always --long --dirty)
+
 # external includes
 include_directories(${OPENGL_INCLUDE_DIR})
     
diff --git a/externals/cmake-modules/GetGitRevisionDescription.cmake b/externals/cmake-modules/GetGitRevisionDescription.cmake
new file mode 100644
index 000000000..2b9cde061
--- /dev/null
+++ b/externals/cmake-modules/GetGitRevisionDescription.cmake
@@ -0,0 +1,130 @@
+# - Returns a version string from Git
+#
+# These functions force a re-configure on each git commit so that you can
+# trust the values of the variables in your build system.
+#
+#  get_git_head_revision(<refspecvar> <hashvar> [<additional arguments to git describe> ...])
+#
+# Returns the refspec and sha hash of the current head revision
+#
+#  git_describe(<var> [<additional arguments to git describe> ...])
+#
+# Returns the results of git describe on the source tree, and adjusting
+# the output so that it tests false if an error occurs.
+#
+#  git_get_exact_tag(<var> [<additional arguments to git describe> ...])
+#
+# Returns the results of git describe --exact-match on the source tree,
+# and adjusting the output so that it tests false if there was no exact
+# matching tag.
+#
+# Requires CMake 2.6 or newer (uses the 'function' command)
+#
+# Original Author:
+# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
+# http://academic.cleardefinition.com
+# Iowa State University HCI Graduate Program/VRAC
+#
+# Copyright Iowa State University 2009-2010.
+# Distributed under the Boost Software License, Version 1.0.
+# (See accompanying file LICENSE_1_0.txt or copy at
+# http://www.boost.org/LICENSE_1_0.txt)
+
+if(__get_git_revision_description)
+        return()
+endif()
+set(__get_git_revision_description YES)
+
+# We must run the following at "include" time, not at function call time,
+# to find the path to this module rather than the path to a calling list file
+get_filename_component(_gitdescmoddir ${CMAKE_CURRENT_LIST_FILE} PATH)
+
+function(get_git_head_revision _refspecvar _hashvar)
+        set(GIT_PARENT_DIR "${CMAKE_CURRENT_SOURCE_DIR}")
+        set(GIT_DIR "${GIT_PARENT_DIR}/.git")
+        while(NOT EXISTS "${GIT_DIR}")  # .git dir not found, search parent directories
+                set(GIT_PREVIOUS_PARENT "${GIT_PARENT_DIR}")
+                get_filename_component(GIT_PARENT_DIR ${GIT_PARENT_DIR} PATH)
+                if(GIT_PARENT_DIR STREQUAL GIT_PREVIOUS_PARENT)
+                        # We have reached the root directory, we are not in git
+                        set(${_refspecvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
+                        set(${_hashvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
+                        return()
+                endif()
+                set(GIT_DIR "${GIT_PARENT_DIR}/.git")
+        endwhile()
+        # check if this is a submodule
+        if(NOT IS_DIRECTORY ${GIT_DIR})
+                file(READ ${GIT_DIR} submodule)
+                string(REGEX REPLACE "gitdir: (.*)\n$" "\\1" GIT_DIR_RELATIVE ${submodule})
+                get_filename_component(SUBMODULE_DIR ${GIT_DIR} PATH)
+                get_filename_component(GIT_DIR ${SUBMODULE_DIR}/${GIT_DIR_RELATIVE} ABSOLUTE)
+        endif()
+        set(GIT_DATA "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/git-data")
+        if(NOT EXISTS "${GIT_DATA}")
+                file(MAKE_DIRECTORY "${GIT_DATA}")
+        endif()
+
+        if(NOT EXISTS "${GIT_DIR}/HEAD")
+                return()
+        endif()
+        set(HEAD_FILE "${GIT_DATA}/HEAD")
+        configure_file("${GIT_DIR}/HEAD" "${HEAD_FILE}" COPYONLY)
+
+        configure_file("${_gitdescmoddir}/GetGitRevisionDescription.cmake.in"
+                "${GIT_DATA}/grabRef.cmake"
+                @ONLY)
+        include("${GIT_DATA}/grabRef.cmake")
+
+        set(${_refspecvar} "${HEAD_REF}" PARENT_SCOPE)
+        set(${_hashvar} "${HEAD_HASH}" PARENT_SCOPE)
+endfunction()
+
+function(git_describe _var)
+        if(NOT GIT_FOUND)
+                find_package(Git QUIET)
+        endif()
+        #get_git_head_revision(refspec hash)
+        if(NOT GIT_FOUND)
+                set(${_var} "GIT-NOTFOUND" PARENT_SCOPE)
+                return()
+        endif()
+        #if(NOT hash)
+        #       set(${_var} "HEAD-HASH-NOTFOUND" PARENT_SCOPE)
+        #       return()
+        #endif()
+
+        # TODO sanitize
+        #if((${ARGN}" MATCHES "&&") OR
+        #       (ARGN MATCHES "||") OR
+        #       (ARGN MATCHES "\\;"))
+        #       message("Please report the following error to the project!")
+        #       message(FATAL_ERROR "Looks like someone's doing something nefarious with git_describe! Passed arguments ${ARGN}")
+        #endif()
+
+        #message(STATUS "Arguments to execute_process: ${ARGN}")
+
+        execute_process(COMMAND
+                "${GIT_EXECUTABLE}"
+                describe
+                ${hash}
+                ${ARGN}
+                WORKING_DIRECTORY
+                "${CMAKE_SOURCE_DIR}"
+                RESULT_VARIABLE
+                res
+                OUTPUT_VARIABLE
+                out
+                ERROR_QUIET
+                OUTPUT_STRIP_TRAILING_WHITESPACE)
+        if(NOT res EQUAL 0)
+                set(out "${out}-${res}-NOTFOUND")
+        endif()
+
+        set(${_var} "${out}" PARENT_SCOPE)
+endfunction()
+
+function(git_get_exact_tag _var)
+        git_describe(out --exact-match ${ARGN})
+        set(${_var} "${out}" PARENT_SCOPE)
+endfunction()
diff --git a/externals/cmake-modules/GetGitRevisionDescription.cmake.in b/externals/cmake-modules/GetGitRevisionDescription.cmake.in
new file mode 100644
index 000000000..888ce13aa
--- /dev/null
+++ b/externals/cmake-modules/GetGitRevisionDescription.cmake.in
@@ -0,0 +1,38 @@
+# 
+# Internal file for GetGitRevisionDescription.cmake
+#
+# Requires CMake 2.6 or newer (uses the 'function' command)
+#
+# Original Author:
+# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
+# http://academic.cleardefinition.com
+# Iowa State University HCI Graduate Program/VRAC
+#
+# Copyright Iowa State University 2009-2010.
+# Distributed under the Boost Software License, Version 1.0.
+# (See accompanying file LICENSE_1_0.txt or copy at
+# http://www.boost.org/LICENSE_1_0.txt)
+
+set(HEAD_HASH)
+
+file(READ "@HEAD_FILE@" HEAD_CONTENTS LIMIT 1024)
+
+string(STRIP "${HEAD_CONTENTS}" HEAD_CONTENTS)
+if(HEAD_CONTENTS MATCHES "ref")
+        # named branch
+        string(REPLACE "ref: " "" HEAD_REF "${HEAD_CONTENTS}")
+        if(EXISTS "@GIT_DIR@/${HEAD_REF}")
+                configure_file("@GIT_DIR@/${HEAD_REF}" "@GIT_DATA@/head-ref" COPYONLY)
+        elseif(EXISTS "@GIT_DIR@/logs/${HEAD_REF}")
+                configure_file("@GIT_DIR@/logs/${HEAD_REF}" "@GIT_DATA@/head-ref" COPYONLY)
+                set(HEAD_HASH "${HEAD_REF}")
+        endif()
+else()
+        # detached HEAD
+        configure_file("@GIT_DIR@/HEAD" "@GIT_DATA@/head-ref" COPYONLY)
+endif()
+
+if(NOT HEAD_HASH)
+        file(READ "@GIT_DATA@/head-ref" HEAD_HASH LIMIT 1024)
+        string(STRIP "${HEAD_HASH}" HEAD_HASH)
+endif()
diff --git a/src/common/CMakeLists.txt b/src/common/CMakeLists.txt
index 738144927..1495e433b 100644
--- a/src/common/CMakeLists.txt
+++ b/src/common/CMakeLists.txt
@@ -1,3 +1,5 @@
+configure_file("${CMAKE_CURRENT_SOURCE_DIR}/scm_rev.cpp.in" "${CMAKE_CURRENT_BINARY_DIR}/scm_rev.cpp" @ONLY)
+
 set(SRCS    break_points.cpp
             console_listener.cpp
             extended_trace.cpp
@@ -15,6 +17,6 @@ set(SRCS    break_points.cpp
             thread.cpp
             timer.cpp
             utf8.cpp
-            version.cpp)
+            ${CMAKE_CURRENT_BINARY_DIR}/scm_rev.cpp)
 
 add_library(common STATIC ${SRCS})
diff --git a/src/common/common.h b/src/common/common.h
index 64a0d7812..a281b21cc 100644
--- a/src/common/common.h
+++ b/src/common/common.h
@@ -12,10 +12,6 @@
 #include <stdio.h>
 #include <string.h>
 
-// SVN version number
-extern const char *g_scm_rev_str;
-extern const char *g_netplay_citra_ver;
-
 // Force enable logging in the right modes. For some reason, something had changed
 // so that debugfast no longer logged.
 #if defined(_DEBUG) || defined(DEBUGFAST)
diff --git a/src/common/emu_window.h b/src/common/emu_window.h
index e70b99ec1..c53d6d7a2 100644
--- a/src/common/emu_window.h
+++ b/src/common/emu_window.h
@@ -5,6 +5,7 @@
 #pragma once
 
 #include "common/common.h"
+#include "common/scm_rev.h"
 
 // Abstraction class used to provide an interface between emulation code and the frontend (e.g. SDL, 
 //  QGLWidget, GLFW, etc...)
@@ -66,7 +67,7 @@ public:
 protected:
     EmuWindow() : m_client_area_width(640), m_client_area_height(480) {
         char window_title[255];
-        sprintf(window_title, "citra-%s", g_scm_rev_str);
+        sprintf(window_title, "citra-%s", Common::g_scm_desc);
         m_window_title = window_title;
     }
     virtual ~EmuWindow() {}
diff --git a/src/common/scm_rev.cpp.in b/src/common/scm_rev.cpp.in
new file mode 100644
index 000000000..9e2bcfdd8
--- /dev/null
+++ b/src/common/scm_rev.cpp.in
@@ -0,0 +1,18 @@
+// Copyright 2014 Citra Emulator Project
+// Licensed under GPLv2
+// Refer to the license.txt file included.
+
+#include "common/scm_rev.h"
+
+#define GIT_REV      "@GIT_REV@"
+#define GIT_REF_SPEC "@GIT_REF_SPEC@"
+#define GIT_DESC     "@GIT_DESC@"
+
+namespace Common {
+
+const char g_scm_rev[]      = GIT_REV;
+const char g_scm_ref_spec[] = GIT_REF_SPEC;
+const char g_scm_desc[]     = GIT_DESC;
+
+} // namespace
+
diff --git a/src/common/scm_rev.h b/src/common/scm_rev.h
new file mode 100644
index 000000000..7f5ce119c
--- /dev/null
+++ b/src/common/scm_rev.h
@@ -0,0 +1,14 @@
+// Copyright 2014 Citra Emulator Project
+// Licensed under GPLv2
+// Refer to the license.txt file included.
+
+#pragma once
+
+namespace Common {
+
+extern const char g_scm_rev[];
+extern const char g_scm_ref_spec[];
+extern const char g_scm_desc[];
+
+} // namespace
+
diff --git a/src/common/version.cpp b/src/common/version.cpp
deleted file mode 100644
index 2e0c7390c..000000000
--- a/src/common/version.cpp
+++ /dev/null
@@ -1,45 +0,0 @@
-// Copyright 2013 Dolphin Emulator Project
-// Licensed under GPLv2
-// Refer to the license.txt file included.
-
-#include "common/common.h"
-#include "common/scm_rev.h"
-
-#ifdef _DEBUG
-    #define BUILD_TYPE_STR "Debug "
-#elif defined DEBUGFAST
-    #define BUILD_TYPE_STR "DebugFast "
-#else
-    #define BUILD_TYPE_STR ""
-#endif
-
-const char *g_scm_rev_str = 
-#if !SCM_IS_MASTER
-    "[" SCM_BRANCH_STR "] "
-#endif
-
-#ifdef __INTEL_COMPILER
-    BUILD_TYPE_STR SCM_DESC_STR "-ICC";
-#else
-    BUILD_TYPE_STR SCM_DESC_STR;
-#endif
-
-#ifdef _M_X64
-#define NP_ARCH "x64"
-#else
-#ifdef _M_ARM
-#define NP_ARCH "ARM"
-#else    
-#define NP_ARCH "x86"
-#endif
-#endif
-
-#ifdef _WIN32
-const char *g_netplay_citra_ver = SCM_DESC_STR " W" NP_ARCH;
-#elif __APPLE__     
-const char *g_netplay_citra_ver = SCM_DESC_STR " M" NP_ARCH;
-#else               
-const char *g_netplay_citra_ver = SCM_DESC_STR " L" NP_ARCH;
-#endif
-
-const char *scm_rev_git_str = SCM_REV_STR;