Build script improvements

1 files changed, 99 insertions, 0 deletions

diff --git a/build.gradle.kts b/build.gradle.kts
new file mode 100644
index 0000000..6b30db9
--- /dev/null
+++ b/build.gradle.kts
@@ -0,0 +1,99 @@
+plugins {
+    `maven-publish`
+    id("org.quiltmc.loom")
+}
+
+val groupid: String by project
+val jakartaAnnotationVersion: String by project
+val loaderVersion: String by project
+val modid: String by project
+val minecraftVersion: String by project
+val patchouliVersion: String by project
+val quiltMappings: String by project
+val quiltedFabricApiVersion: String by project
+
+base {
+    archivesName = modid
+}
+
+version = "0.1+${minecraftVersion}"
+group = groupid
+
+repositories {
+    maven {
+        url = uri("https://maven.blamejared.com")
+        content {
+            includeGroup("vazkii.patchouli")
+        }
+    }
+}
+
+loom {
+    mods {
+        register(modid) {
+            sourceSet("main")
+        }
+    }
+}
+
+dependencies {
+    minecraft("com.mojang:minecraft:${minecraftVersion}")
+    mappings(loom.layered {
+        mappings("org.quiltmc:quilt-mappings:${minecraftVersion}+build.${quiltMappings}:intermediary-v2")
+        officialMojangMappings()
+    })
+    modImplementation("org.quiltmc:quilt-loader:${loaderVersion}")
+    modImplementation("org.quiltmc.quilted-fabric-api:quilted-fabric-api:${quiltedFabricApiVersion}-${minecraftVersion}")
+
+    modImplementation("vazkii.patchouli:Patchouli:${patchouliVersion}") {
+        exclude(group = "net.fabricmc", module = "fabric-loader")
+    }
+
+    compileOnly("jakarta.annotation:jakarta.annotation-api:${jakartaAnnotationVersion}")
+}
+
+tasks.processResources {
+    inputs.property("loader_version", loaderVersion)
+    inputs.property("minecraft_version", minecraftVersion)
+    inputs.property("patchouli_version", patchouliVersion)
+    inputs.property("quilted_fabric_api_version", quiltedFabricApiVersion)
+    inputs.property("version", version)
+
+    filesMatching("quilt.mod.json") {
+        expand(
+                "loader_version" to loaderVersion,
+                "minecraft_version" to minecraftVersion,
+                "patchouli_version" to patchouliVersion,
+                "quilted_fabric_api_version" to quiltedFabricApiVersion,
+                "version" to version
+        )
+    }
+}
+
+tasks.withType<JavaCompile>().configureEach {
+    options.encoding = "UTF-8"
+    options.release = 17
+}
+
+java {
+    sourceCompatibility = JavaVersion.VERSION_17
+    targetCompatibility = JavaVersion.VERSION_17
+
+    withSourcesJar()
+}
+
+tasks.jar {
+    from("LICENSE") {
+        rename { "${it}_${base.archivesName.get()}" }
+    }
+}
+
+publishing {
+    publications {
+        create<MavenPublication>("maven") {
+            from(components["java"])
+        }
+    }
+
+    repositories {}
+}